/*



Story 4: Does Smoking Improve Survival? in the EESEE Expansion Modules

 in the website for the text (link from course descripton)



http://WWW.WHFREEMAN.COM/STATISTICS/IPS/EESEE4/EESEES4.HTM



A survey concerned with thyroid and heart disease was conducted

in 1972-74 in a district near Newcastle, United Kingdom by Tunbridge

et al (1977). A follow-up study of the same subjects was conducted

twenty years later by Vanderpump et al (1996). Here we explore data

from the survey on the smoking habits of 1314 women who were classified

as being a current smoker or as never having smoked at the time of the

original survey. Of interest is whether or not they survived until the

second survey.



see jh's notes on epi to accompany M&M Ch 9



and Rothman2002, page 2



*/



OPTIONS PS=50 LS=75; RUN;



PROC FORMAT;

VALUE onefirst 0="z_0" 1="a_1";

RUN;



DATA sasuser.simpson;

INPUT age $ i_smoke i_dead  number;



         /* number instead of individual per line */



LINES;

18-44 1  1   19

18-44 1  0  269

18-44 0  1   13

18-44 0  0  327

44-64 1  1   78

44-64 1  0  167

44-64 0  1   52

44-64 0  0  147

64-   1  1   42

64-   1  0    7

64-   0  1  165

64-   0  0   28

;



run;

options ls = 75 ps = 50; run;



TITLE 'crude comparison'; RUN;



PROC FREQ DATA=sasuser.simpson ORDER=FORMATTED;



TABLES      i_smoke * i_dead /

   NOCOL NOROW NOPERCENT

   CMH EXPECTED;                   /* turn on all output */



 FORMAT i_smoke i_dead onefirst. ; /* to orient tables for m-h */



 WEIGHT number;                    /* using weight to indicate multiples */



run;



TITLE 'adjusted comparison'; RUN;



PROC FREQ DATA=sasuser.simpson ORDER=FORMATTED;



TABLES age * i_smoke * i_dead /

   NOCOL NOROW NOPERCENT

   CMH EXPECTED;                   /* turn on all output */



 FORMAT i_smoke i_dead onefirst. ; /* to orient tables so */



 WEIGHT number;                    /* using weight to indicate multiples */



run;